From c01109ec361c66bd3f697c8ece220f2ba0214c87 Mon Sep 17 00:00:00 2001
From: Frank Ralf <webmaster@nakohdo.de>
Date: Mon, 13 Apr 2015 22:36:55 +0200
Subject: [PATCH 4/4] Add DITA template. 	new file:  
 templates/ditaxhtml2simplehtml.xsl

---
 templates/ditaxhtml2simplehtml.xsl | 100 +++++++++++++++++++++++++++++++++++++
 1 file changed, 100 insertions(+)
 create mode 100644 templates/ditaxhtml2simplehtml.xsl
diff --git a/templates/ditaxhtml2simplehtml.xsl b/templates/ditaxhtml2simplehtml.xsl
new file mode 100644
index 0000000..f926844
--- /dev/null
+++ b/templates/ditaxhtml2simplehtml.xsl
@@ -0,0 +1,100 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+  xmlns="http://www.w3.org/1999/xhtml" xmlns:xhtml="http://www.w3.org/1999/xhtml">
+  <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
+  <!-- 
+    ####################################
+    File:     ditaxhtml2simplehtml.xsl
+    Based on: simplehtml2simplehtml.xsl
+        
+    For importing the XHTML output of the DITA Open Toolkit (DITA-OT),
+    see http://www.dita-ot.org/1.8/readme/dita2xhtml.html
+    
+    DITA elements are usually addressed by their @class attribute instead 
+    of the element name:
+    
+    "The @class attribute usually provides a mapping from the element's 
+    current name to its more general equivalents, but it can also provide 
+    a mapping from the current name to more general and more specialized equivalents. 
+    All specialization-aware processing can be defined in terms of @class attribute values
+    without reference to a given element's tagname."
+    See http://docs.oasis-open.org/dita/v1.2/os/spec/archSpec/classatt.html
+    
+    You have to set the Ant parameter "args.xhtml.toc.class" to the value "index" which will become the @class attribute of the body element of the resulting index.html file.
+    See http://www.dita-ot.org/1.8/readme/ant-parameters-xhtml-transformation.html
+    
+  -->
+
+  <xsl:template name="html_doc" match="/*">
+    <!-- 
+    Main page layout.
+    Head and body are the immediate children.
+    -->
+    <html>
+      <head>
+        <!-- META And Header extraction -->
+        <title>
+          <xsl:call-template name="get-title"/>
+        </title>
+
+        <xsl:for-each select="//xhtml:meta[@name]|//meta[@name]|//xhtml:rel|//rel">
+          <!-- Copy most of the head - but NOT metas with http-equiv -->
+          <xsl:copy>
+            <xsl:for-each select="@*">
+              <xsl:copy/>
+            </xsl:for-each>
+          </xsl:copy>
+        </xsl:for-each>
+      </head>
+      <body>
+        <!-- Page title -->
+        <h1 id="pagetitle" xml:id="pagetitle">
+          <xsl:call-template name="get-title"/>
+        </h1>
+        <!-- Main content -->
+        <div id="content" xml:id="content">
+          <xsl:call-template name="get-content"/>
+        </div>
+        <!-- Related links -->
+        <div id="related-links" xml:id="related-links">
+          <xsl:call-template name="get-related-links"/>
+        </div>
+      </body>
+    </html>
+  </xsl:template>
+
+
+  <xsl:template name="get-title">
+    <xsl:value-of select="//title|//xhtml:title|//*[contains(@class, 'title')]"/>
+  </xsl:template>
+
+  <xsl:template name="get-content">
+    <!-- Content of index file -->
+    <xsl:apply-templates select="//*[contains(@class, 'index')]"/>
+    <!-- Content of topic file -->
+    <xsl:apply-templates
+      select="
+        //*[contains(@class, 'body') or 
+            contains(@class, 'abstract')]
+    "
+    />
+  </xsl:template>
+
+  <xsl:template name="get-related-links">
+    <xsl:apply-templates select="//*[contains(@class, 'related-links')]"/>
+  </xsl:template>
+
+  <!-- Identity transformation template - to inline existing HTML  -->
+  <xsl:template name="passthrough" match="@*|node()|text()">
+    <xsl:copy>
+      <xsl:apply-templates select="@*|node()|text()"/>
+      <!-- Fatten all empty tags (anorexic divs are a failure) but not known singletons -->
+      <xsl:if
+        test="not (node()|text()) and not(local-name()='img') and not(local-name()='br') and not(local-name()='hr') ">
+        <xsl:text> </xsl:text>
+      </xsl:if>
+    </xsl:copy>
+  </xsl:template>
+
+</xsl:stylesheet>
-- 
1.8.4.msysgit.0

